libtetrabz_dblstep_mod.F90

Go to the documentation of this file.

!
! Copyright (c) 2014 Mitsuaki Kawamura
!
! Permission is hereby granted, free of charge, to any person obtaining a
! copy of this software and associated documentation files (the
! "Software"), to deal in the Software without restriction, including
! without limitation the rights to use, copy, modify, merge, publish,
! distribute, sublicense, and/or sell copies of the Software, and to
! permit persons to whom the Software is furnished to do so, subject to
! the following conditions:
! 
! The above copyright notice and this permission notice shall be included
! in all copies or substantial portions of the Software.
!
! THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
! OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
! MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
! IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
! CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
! TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
! SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
!
MODULE libtetrabz_dblstep_mod
  !
  IMPLICIT NONE
  !
  PRIVATE
  PUBLIC libtetrabz_dblstep
  !
CONTAINS
!
! Compute Occ * Step
!
SUBROUTINE libtetrabz_dblstep(ltetra,bvec,nb,nge,eig1,eig2,ngw,wght,comm) BIND(C)
  !
  USE iso_c_binding
  USE libtetrabz_common, ONLY : libtetrabz_initialize, libtetrabz_interpol_indx, libtetrabz_mpisum_dv
  IMPLICIT NONE
  !
  INTEGER(C_INT),INTENT(IN) :: ltetra, nb, nge(3), ngw(3)
  REAL(c_double),INTENT(IN) :: bvec(9), eig1(nb,product(nge(1:3))), eig2(nb,product(nge(1:3)))
  REAL(c_double),INTENT(OUT) :: wght(nb*nb,product(ngw(1:3)))
  INTEGER(C_INT),INTENT(IN),OPTIONAL :: comm
  !
  LOGICAL :: linterpol
  INTEGER :: nt_local, nk_local, nkbz, ik, kintp(8)
  INTEGER,ALLOCATABLE :: ik_global(:,:), ik_local(:,:)
  REAL(8) :: wlsm(4,20), wintp(1,8)
  REAL(8),ALLOCATABLE :: wghtd(:,:,:), kvec(:,:)
  !
  IF(PRESENT(comm)) THEN
     CALL libtetrabz_initialize(ltetra,nge,ngw,bvec,linterpol,wlsm,nk_local,&
     &                          nt_local,nkbz,ik_global,ik_local,kvec,comm)
  ELSE
     CALL libtetrabz_initialize(ltetra,nge,ngw,bvec,linterpol,wlsm,nk_local,&
     &                          nt_local,nkbz,ik_global,ik_local,kvec)
  END IF
  !
  IF(linterpol) THEN
     !
     ALLOCATE(wghtd(nb*nb,1,nk_local))
     CALL libtetrabz_dblstep_main(wlsm,nt_local,ik_global,ik_local,nb,nkbz,eig1,eig2,nk_local,wghtd)
     !
     ! Interpolation
     !
     wght(1:nb*nb,1:product(ngw(1:3))) = 0d0
     DO ik = 1, nk_local
        CALL libtetrabz_interpol_indx(ngw,kvec(1:3,ik),kintp,wintp)
        wght(1:nb*nb,kintp(1:8)) = wght(1:nb*nb,             kintp(1:8)) &
        &                + matmul(wghtd(1:nb*nb,1:1,ik), wintp(1:1,1:8))
     END DO ! ik = 1, nk_local
     DEALLOCATE(wghtd, kvec)
     !
     IF(PRESENT(comm)) CALL libtetrabz_mpisum_dv(comm, nb*nb*product(ngw(1:3)), wght)
     !
  ELSE
     CALL libtetrabz_dblstep_main(wlsm,nt_local,ik_global,ik_local,nb,nkbz,eig1,eig2,nk_local,wght)
  END IF
  !
  DEALLOCATE(ik_global, ik_local)
  !
END SUBROUTINE libtetrabz_dblstep
!
! Main SUBROUTINE for Theta(- E1) * Theta(E1 - E2)
!
SUBROUTINE libtetrabz_dblstep_main(wlsm,nt_local,ik_global,ik_local,nb,nkBZ,eig1,eig2,nk_local,dblstep)
  !
  USE libtetrabz_common, ONLY : libtetrabz_sort, &
  &                             libtetrabz_tsmall_a1, libtetrabz_tsmall_b1, &
  &                             libtetrabz_tsmall_b2, libtetrabz_tsmall_b3, &
  &                             libtetrabz_tsmall_c1, libtetrabz_tsmall_c2, &
  &                             libtetrabz_tsmall_c3
  IMPLICIT NONE
  !
  INTEGER,INTENT(IN) :: nt_local, nb, nkBZ, nk_local, &
  &                     ik_global(20,nt_local), ik_local(20,nt_local)
  REAL(8),INTENT(IN) :: wlsm(4,20), eig1(nb,nkBZ), eig2(nb,nkBZ)
  REAL(8),INTENT(OUT) :: dblstep(nb,nb,nk_local)
  !
  INTEGER :: ib, indx(4), it
  REAL(8) :: e(4), ei1(4,nb), ei2(4), ej1(4,nb), ej2(4,nb), thr = 1d-10, &
  &          tsmall(4,4), v, w1(nb,4), w2(nb,4)
  !
  dblstep(1:nb,1:nb,1:nk_local) = 0d0
  !
  !$OMP PARALLEL DEFAULT(NONE) &
  !$OMP & SHARED(dblstep,eig1,eig2,ik_global,ik_local,nb,nt_local,thr,wlsm) &
  !$OMP & PRIVATE(e,ei1,ei2,ej1,ej2,ib,indx,it,tsmall,V,w1,w2)
  !
  DO it = 1, nt_local
     !
     DO ib = 1, nb
        ei1(1:4, ib) = matmul(wlsm(1:4,1:20), eig1(ib, ik_global(1:20,it)))
        ej1(1:4, ib) = matmul(wlsm(1:4,1:20), eig2(ib, ik_global(1:20,it)))
     END DO
     !
     !$OMP DO
     DO ib = 1, nb
        !
        w1(1:nb,1:4) = 0d0
        e(1:4) = ei1(1:4, ib)
        CALL libtetrabz_sort(4,e,indx)
        !
        IF(e(1) <= 0d0 .AND. 0d0 < e(2) ) THEN
           !
           CALL libtetrabz_tsmall_a1(e,v,tsmall)
           !
           IF(v > thr) THEN
              !
              ei2(1:4     ) = matmul(tsmall(1:4,1:4), ei1(indx(1:4),  ib))
              ej2(1:4,1:nb) = matmul(tsmall(1:4,1:4), ej1(indx(1:4),1:nb))
              CALL libtetrabz_dblstep2(nb,ei2,ej2,w2)
              w1(1:nb,indx(1:4)) = w1(1:nb,              indx(1:4)) &
              &       + v * matmul(w2(1:nb, 1:4 ), tsmall(1:4,1:4))
              !
           END IF
           !
        ELSE IF(e(2) <= 0d0 .AND. 0d0 < e(3)) THEN
           !
           CALL libtetrabz_tsmall_b1(e,v,tsmall)
           !
           IF(v > thr) THEN
              !
              ei2(1:4     ) = matmul(tsmall(1:4,1:4), ei1(indx(1:4),  ib))
              ej2(1:4,1:nb) = matmul(tsmall(1:4,1:4), ej1(indx(1:4),1:nb))
              CALL libtetrabz_dblstep2(nb,ei2,ej2,w2)
              w1(1:nb,indx(1:4)) = w1(1:nb,            indx(1:4)) &
              &       + v * matmul(w2(1:nb,1:4), tsmall(1:4,1:4))
              !
           END IF
           !
           CALL libtetrabz_tsmall_b2(e,v,tsmall)
           !
           IF(v > thr) THEN
              !
              ei2(1:4     ) = matmul(tsmall(1:4,1:4), ei1(indx(1:4),  ib))
              ej2(1:4,1:nb) = matmul(tsmall(1:4,1:4), ej1(indx(1:4),1:nb))
              CALL libtetrabz_dblstep2(nb,ei2,ej2,w2)
              w1(1:nb,indx(1:4)) = w1(1:nb,            indx(1:4)) &
              &       + v * matmul(w2(1:nb,1:4), tsmall(1:4,1:4))
              !
           END IF
           !
           CALL libtetrabz_tsmall_b3(e,v,tsmall)
           !
           IF(v > thr) THEN
              !
              ei2(1:4     ) = matmul(tsmall(1:4,1:4), ei1(indx(1:4),  ib))
              ej2(1:4,1:nb) = matmul(tsmall(1:4,1:4), ej1(indx(1:4),1:nb))
              CALL libtetrabz_dblstep2(nb,ei2,ej2,w2)
              w1(1:nb,indx(1:4)) = w1(1:nb,            indx(1:4)) &
              &       + v * matmul(w2(1:nb,1:4), tsmall(1:4,1:4))
              !
           END IF
           !
        ELSE IF( e(3) <= 0d0 .AND. 0d0 < e(4)) THEN
           !
           CALL libtetrabz_tsmall_c1(e,v,tsmall)
           !
           IF(v > thr) THEN
              !
              ei2(1:4     ) = matmul(tsmall(1:4,1:4), ei1(indx(1:4),  ib))
              ej2(1:4,1:nb) = matmul(tsmall(1:4,1:4), ej1(indx(1:4),1:nb))
              CALL libtetrabz_dblstep2(nb,ei2,ej2,w2)
              w1(1:nb,indx(1:4)) = w1(1:nb,            indx(1:4)) &
              &       + v * matmul(w2(1:nb,1:4), tsmall(1:4,1:4))
              !
           END IF
           !
           CALL libtetrabz_tsmall_c2(e,v,tsmall)
           !
           IF(v > thr) THEN
              !
              ei2(1:4     ) = matmul(tsmall(1:4,1:4), ei1(indx(1:4),  ib))
              ej2(1:4,1:nb) = matmul(tsmall(1:4,1:4), ej1(indx(1:4),1:nb))
              CALL libtetrabz_dblstep2(nb,ei2,ej2,w2)
              w1(1:nb,indx(1:4)) = w1(1:nb,            indx(1:4)) &
              &       + v * matmul(w2(1:nb,1:4), tsmall(1:4,1:4))
              !
           END IF
           !
           CALL libtetrabz_tsmall_c3(e,v,tsmall)
           !
           IF(v > thr) THEN
              !
              ei2(1:4     ) = matmul(tsmall(1:4,1:4), ei1(indx(1:4),  ib))
              ej2(1:4,1:nb) = matmul(tsmall(1:4,1:4), ej1(indx(1:4),1:nb))
              CALL libtetrabz_dblstep2(nb,ei2,ej2,w2)
              w1(1:nb,indx(1:4)) = w1(1:nb,            indx(1:4)) &
              &       + v * matmul(w2(1:nb,1:4), tsmall(1:4,1:4))
              !
           END IF
           !
        ELSE IF(e(4) <= 0d0) THEN
           !
           ei2(1:4     ) = ei1(1:4,  ib)
           ej2(1:4,1:nb) = ej1(1:4,1:nb)
           CALL libtetrabz_dblstep2(nb,ei2,ej2,w2)
           w1(1:nb,1:4) = w1(1:nb,1:4) + w2(1:nb,1:4)
           !
        ELSE
           !
           cycle
           !
        END IF
        !
        dblstep(1:nb,ib,ik_local(1:20,it)) = dblstep(1:nb,ib,    ik_local(1:20,it)) &
        &                                + matmul(w1(1:nb, 1:4), wlsm(1:4,1:20))
        !
     END DO ! ib
     !$OMP END DO NOWAIT
     !
  END DO ! it
  !
  !$OMP END PARALLEL
  !
  dblstep(1:nb,1:nb,1:nk_local) = dblstep(1:nb,1:nb,1:nk_local) / dble(6 * nkbz)
  !
END SUBROUTINE libtetrabz_dblstep_main
!
! Tetrahedra method for theta( - de)
!
SUBROUTINE libtetrabz_dblstep2(nb,ei1,ej1,w1)
  !
  USE libtetrabz_common, ONLY : libtetrabz_sort, &
  &                             libtetrabz_tsmall_a1, libtetrabz_tsmall_b1, &
  &                             libtetrabz_tsmall_b2, libtetrabz_tsmall_b3, &
  &                             libtetrabz_tsmall_c1, libtetrabz_tsmall_c2, &
  &                             libtetrabz_tsmall_c3
  IMPLICIT NONE
  !
  INTEGER,INTENT(IN) :: nb
  REAL(8),INTENT(IN) :: ei1(4), ej1(4,nb)
  REAL(8),INTENT(OUT) :: w1(nb,4)
  !
  INTEGER :: ib, indx(4)
  REAL(8) :: e(4), thr = 1d-8, tsmall(4,4), v
  !
  DO ib = 1, nb
     !
     w1(ib,1:4) = 0d0
     e(1:4) = - ei1(1:4) + ej1(1:4,ib)
     CALL libtetrabz_sort(4,e,indx)
     !
     IF(abs(e(1)) < thr .AND. abs(e(4)) < thr) THEN
        !
        ! Theta(0) = 0.5
        !
        v = 0.5d0
        w1(ib,1:4) = w1(ib,1:4) + v * 0.25d0
        !
     ELSE IF((e(1) <= 0d0 .AND. 0d0 < e(2)) .OR. (e(1) < 0d0 .AND. 0d0 <= e(2))) THEN
        !
        CALL libtetrabz_tsmall_a1(e,v,tsmall)
        w1(ib,indx(1:4)) = w1(ib,indx(1:4)) + v * sum(tsmall(1:4,1:4), 1) * 0.25d0
        !
     ELSE IF((e(2) <= 0d0 .AND. 0d0 < e(3)) .OR. (e(2) < 0d0 .AND. 0d0 <= e(3))) THEN
        !
        CALL libtetrabz_tsmall_b1(e,v,tsmall)
        w1(ib,indx(1:4)) = w1(ib,indx(1:4)) + v * sum(tsmall(1:4,1:4), 1) * 0.25d0
        !
        CALL libtetrabz_tsmall_b2(e,v,tsmall)
        w1(ib,indx(1:4)) = w1(ib,indx(1:4)) + v * sum(tsmall(1:4,1:4), 1) * 0.25d0
        !
        CALL libtetrabz_tsmall_b3(e,v,tsmall)
        w1(ib,indx(1:4)) = w1(ib,indx(1:4)) + v * sum(tsmall(1:4,1:4), 1) * 0.25d0
        !
     ELSE IF((e(3) <= 0d0 .AND. 0d0 < e(4)) .OR. (e(3) < 0d0 .AND. 0d0 <= e(4))) THEN
        !
        CALL libtetrabz_tsmall_c1(e,v,tsmall)
        w1(ib,indx(1:4)) = w1(ib,indx(1:4)) + v * sum(tsmall(1:4,1:4), 1) * 0.25d0
        !
        CALL libtetrabz_tsmall_c2(e,v,tsmall)
        w1(ib,indx(1:4)) = w1(ib,indx(1:4)) + v * sum(tsmall(1:4,1:4), 1) * 0.25d0
        !
        CALL libtetrabz_tsmall_c3(e,v,tsmall)
        w1(ib,indx(1:4)) = w1(ib,indx(1:4)) + v * sum(tsmall(1:4,1:4), 1) * 0.25d0
        !
     ELSE IF(e(4) <= 0d0) THEN
        !
        w1(ib,1:4) = w1(ib,1:4) + 0.25d0
        !
     END IF
     !
  END DO ! ib = 1, nb
  !
END SUBROUTINE libtetrabz_dblstep2
!
END MODULE libtetrabz_dblstep_mod